"Demo delle funzionalità di Vorple" by Juhana Leinonen (in Italian)

[
Translated in Italian by Leonardo Boselli <leonardo.boselli@youdev.it> from the original in English "Vorple Features Demo" by Juhana Leinonen.
Requires the extension "Italian Language" by Massimo Stella available here: https://sourceforge.net/projects/milleuna/files/Extensions/3.0/
]

Release along with the "Vorple" interpreter.
Release along with source text.

Book 1 - Setup

The Corridoio is a room. "Da [qui] [puoi] accedere ad alcune porte che conducono a differenti dimostrazioni delle funzionalità.
[ul][li][link to north]: Funzionalità fondamentali.[/li][li][link to east]: Controllo della linea di comando.[/li][li][link to south]: Multimedialità.[/li][li][link to west]: Effetti video.[/li][li][link to up]: Notifiche.[/li][/ul]I collegamenti ipertestuali vengono usati abbondantemente."

To say ul:
	if Vorple is supported:
		open HTML tag "ul";
	otherwise:
		say line break.
	
To say /ul:
	if Vorple is supported:
		close HTML tag;
	otherwise:
		say paragraph break.

To say li:
	if Vorple is supported:
		open HTML tag "li";
	otherwise:
		say line break.

To say /li:
	close HTML tag.

To say link to (d - direction):
	let uppercase dir be "[d]" in upper case;
	place a link to command "[uppercase dir]" reading uppercase dir.


Part 1 - Credits

After printing the banner text when Vorple is supported:
	say "Musica di Eric Matyas (";
	place a link to web site "http://www.soundimage.org" reading "www.soundimage.org";
	say ")[line break]".


Book 2 - Core

Include Vorple by Juhana Leinonen.

The Libreria (f) is north of the Corridoio. The description is "Questa libreria è piuttosto spoglia - contiene un solo volume intitolato [italic type][Enciclopedia del Tutto][roman type]. CONSULTA quasiasi cosa desideri in questo volume."

The currently demonstrated feature of the Libreria is "Funzionalità fondamentali".


Part 1 - Realtime Clock

The orologio a pendolo is in the Libreria. "Un orologio a pendolo mostra che sono le [current time]." The description is "L[']orologio segna le [current time]." The orologio a pendolo is fixed in place.
Understand "pendola" as orologio a pendolo.

To say current time:
	if Vorple is supported:
		execute JavaScript command "var now = new Date(); ((now.getHours()%24)||24)+':'+('0'+now.getMinutes()).slice(-2)";
		say the text returned by the JavaScript command;
	otherwise:
		say "[time of day]".


Part 2 - Wikipedia
	
Release along with JavaScript "encyclopedia.js".

The Enciclopedia del Tutto (f) is in the Libreria. The description is "Questo libro dichiara di contenere tutta la conoscenza umana.

[italic type]Usa il comando CONSULTA seguito dall[']argomento che vuoi leggere nel libro.[roman type]"

Understand "libro" as the Enciclopedia del Tutto.

Instead of consulting the Enciclopedia del Tutto about when Vorple is supported:
	place a block level element called "dictionary-entry";
	execute JavaScript command "wikipedia_query('[escaped topic understood]')";
	say run paragraph on;
	block the user interface. [the Wikipedia script will unblock the UI]
		
After consulting the Enciclopedia del Tutto about when Vorple is not supported:
	say "Trovi il capitolo corrispondente e leggi quanto riguarda [topic understood].".
	
Looking up is an action applying to one topic.
Understand "consulta [text]" as looking up.
Understand "leggi [text]" as looking up.

Instead of looking up when the player can see the Enciclopedia del Tutto:
	try consulting the Enciclopedia del Tutto about the topic understood.
	 	
Test wikipedia with "consulta Pippo / consulta Oceano Atlantico / consulta Italia".

Book 3 - Command Prompt Control

Include Vorple Command Prompt Control by Juhana Leinonen

The Ufficio is east of Corridoio.
The currently demonstrated feature of the Ufficio is "Controllo della linea di comando".

Part 1 - Prefilling the prompt

After issuing the response text of a response (called R):
	if R is parser clarification internal rule response (D) or R is parser clarification internal rule response (E):
		prefill the command line with "[parser command so far] ".
		
A scrivania (f) is in the Ufficio. The scrivania is fixed in place. A memo is on the scrivania. The description is "Il memo dice, 'Prova a scrivere un comando parziale che genera la domanda 'Cosa vuoi fare...', come PRENDI, e osserva ciò che accade alla linea di comando successiva.'"

Part 2 - Changing the previous command

Leccapiedi is in the Ufficio. It is fixed in place. "Qui c[']è un robot dall[']aspetto amichevole. 'Ciao! Il mio nome è Leccapiedi,' dice. 'Per favore, [PARLAMI]!'"

To say PARLAMI:
	place a link to command "PARLA A LECCAPIEDI" reading "PARLAMI".	

Leccapiedi is proper-named. Understand "robot" as Leccapiedi.

The can't talk to a non-person rule is not listed in any rulebook.
The standard report talking to rule is not listed in any rulebook.

Check talking to when the noun is not Leccapiedi:
	say "[The noun] non ha voglia di parlare."
	
Carry out talking to Leccapiedi:
	say "'Ciao! Sono Leccapiedi! Quando mi parli, puoi solo dire sì!'[paragraph break]'[one of]Capisci[or]Quindi ti diverti[or]Puoi dire sì[or]Pensi che funzionerà se provi ancora una volta[stopping]?'[paragraph break]";
	if the player consents:
		say "'Bene! La prossima volta prova a dire no, se ci riesci!'";
	otherwise:
		if Vorple is supported:
			change the text of the player's previous command to "sì";
			change the last command in the command history to "sì";
			say "'[one of]Mi fa piacere sentirlo[or]Buon per te[or]Sii positivo[or]Anche io lo penso[or]Molto bene allora[at random]!'";
		otherwise:
			say "'Beh, avrebbe funzionato con un interprete Vorple...' dice il robot con un poco di disappunto."
 
Book 4 - Hyperlinks

Include Vorple Hyperlinks by Juhana Leinonen.


Book 5 - Multimedia

Include Vorple Multimedia by Juhana Leinonen.
Release along with the file "Great-Minds.mp3".

The Galleria (f) is south of Corridoio. "La galleria espone tre dipinti: [Speranza], [Primavera] e [Acheloo]."
The currently demonstrated feature of the Galleria is "Multimedialità".

A targa di ringraziamento is in the Galleria. "C[']è una targa sulla parete con scritto [CREDITS link]." The description is "[multimedia credits]".

To say CREDITS link:
	place a link to command "LEGGI LA TARGA" reading "un ringraziamento".

To say multimedia credits:
	say "Musica di Eric Matyas[paragraph break]";
	place a link to web site "http://www.soundimage.org" reading "www.soundimage.org";
	

Part 1 - Images

Release along with the file "Vorple-header.png".
Release along with the file "Hope.jpg".
Release along with the file "Primavera.jpg".
Release along with the file "Achelous and Hercules.jpg".

A painting is a kind of thing. Speranza, Primavera and Acheloo are paintings in the Galleria.
Understand "dipinto" and "immagine" as a painting.

A painting has some text called the corresponding image file.

The corresponding image file of Speranza is "Hope.jpg".
The corresponding image file of Primavera is "Primavera.jpg".
The corresponding image file of Acheloo is "Achelous and Hercules.jpg".

The printed name of Acheloo is "Acheloo ed Ercole". Understand "Ercole" and "Acheloo ed Ercole" as Acheloo.

Instead of examining a painting:
	if Vorple is supported:
		place an image corresponding image file of the noun with description "[Noun]", centered;
	otherwise:
		say "Ammiri [Noun] per qualche tempo."
	
When play begins:
	if Vorple is supported:
		place an image "Vorple-header.png" with description "Vorple".
		

Part 2 - Audio

After going to the Galleria:
	play music file "Great-Minds.mp3";
	continue the action.
	
After going from the Galleria:
	stop music;
	continue the action.


Book 6 - Notifications

Include Vorple Notifications by Juhana Leinonen.

The Sala di Controllo (f) is up from Corridoio.
The currently demonstrated feature of Sala di Controllo is "Notifiche".

The pannello di controllo is in the Sala di Controllo. "[Qui] c[']è un pannello di controllo con quattro pulsanti: [un pulsante informazioni], [un pulsante di successo], [un pulsante di avvertimento] e [un pulsante di errore]."

The pannello di controllo is fixed in place.

A notification button is a kind of thing.
Understand "pulsante" as a notification button.

A pulsante informazioni, a pulsante di successo, a pulsante di avvertimento and an pulsante di errore are notification buttons. The pulsante informazioni, the pulsante di successo, the pulsante di avvertimento and the pulsante di errore are part of the pannello di controllo.

Rule for printing the name of a notification button (called this one) while looking and Vorple is supported:
	let name be "[printed name of this one]" in upper case;
	place a link to command "PREMI [name]" reading "[printed name of this one]".

Instead of pushing the pulsante informazioni:
	display an info notification with title "Prendi nota" reading "Nessun animale e['] stato ferito o ucciso durante la produzione di questa demo.".
	
Instead of pushing the pulsante di successo:
	display a success notification with title "Successo!" reading "Hai premuto il pulsante con successo.".
	
Instead of pushing the pulsante di avvertimento:
	display a warning notification with title "Avvertimento" reading "Non utilizzare una forza eccessiva nel premere i pulsanti."
	
Instead of pushing the pulsante di errore:
	display an error notification with title "Errore di sistema" reading "Questo pulsante non funziona."

Before pushing a notification button:
	say "Un altoparlante nascosto si attiva."

Understand "premi [things]" or "premi [art-det] [something]" as pushing.

Book 7 - Screen Effects

Include Vorple Screen Effects by Juhana Leinonen.

The Sala Ricreativa is west of Corridoio.
The currently demonstrated feature of Sala Ricreativa is "Effetti video".


Part 1 - Styles

The lista degli stili di testo is in the Sala Ricreativa.

Instead of examining the lista degli stili di testo:
	say "Questa è la lista completa di tutti gli stili forniti dall[']estensione 'Vorple Screen Effects'.[paragraph break]";
	repeat with X running through Vorple styles:
		say "[X style][X][end style][line break]";
	repeat with X running from 1 to 6:
		place a "h[X]" element reading "Level [X] header";
	display an ordered list { "one", "two", "three" };
	display an unordered list { "four", "five", "six" };
	say "Una [green letters style]rana[end style] salta nello [white letters style][blue background style]stagno[end style][end style].";


[
The status lne extension isn't ready.

Book 8 - Status Line

Include Vorple Status Line by Juhana Leinonen.

When play begins:
	now the left hand status line is "[the player's surroundings]";
	now the right hand status line is "[the currently demonstrated feature of the location]";
	now the mobile Vorple status line is "[the player's surroundings][line break][the currently demonstrated feature of the location]";
	construct a Vorple status line with 2 columns.

]

A room has some text called currently demonstrated feature.